• Names of messages are the names of the methods, that the object must find and invoke on behalf of the programmer
• Message operator ("twiddle") is the tilde character: ~
  • "ABC"~REVERSE yields: CBA
• "Cascading" messages, two twiddles: ~~
  • "ABC"~~REVERSE yields (attention!): ABC
  • Sent messages activate the respective methods of the receiving object, upon return the interpreter changes the result to be always the receiving object!
    • Therefore multiple messages intended for the same object can be "cascaded" one after the other ("cascading messages)
• Execution (resolution) of messages: from left to right

Object Rexx implementation of the ADT Birthday

/**/
g1 = .Birthday~New
g1~Date= "20320901"
g1~Time= "16:00"
g2=.Birthday~New~~"Date="("20360229")~~"Time="("19:19")
SAY g1~date g2~date g1~time g2~time

::CLASS  Birthday
::ATTRIBUTE date
::ATTRIBUTE time

Output:

20320901 20360229 16:00 19:19

• The NEW method will create the new object (instance, value) and will send it the message INIT to allow it to initialise
  • If the NEW message has arguments, they get forwarded with the INIT message in the same order
• The NEW method returns the reference to the newly created object (instance, value) as its result

• If there is a method named UNINIT defined for a class, then this method will be invoked, right before the unreferenced object gets destructed by the garbage collector by sendig it the UNINIT message.

• Allows classification of instances (Objects), e.g. from biology
• Ordering of classes in superclasses and subclasses (schemata)
  • Subordered classes ("subclasses") inherit all properties (attributes and methods) of all superclasses up to and including the root class
  • Subclasses specialize in one way or the other the superclass(es)
    • "Defining of differences": simplifies the definition of subclasses
• Sometimes it may make sense, that a subclass specializes directly more than one superclass at the same time ("multiple inheritance")
  • Example: Classes representing landborne and waterborne animals, where there exists a class "amphibians", which inherits directly from the landborne and waterborne animals

• "Special Interest Group (SIG) Dog Sanctuary"
  • Normal dogs
  • Little dogs
  • Big dogs
• All dogs possess a name and are able to bark
  • Normal dogs bark "Wuff Wuff"
  • Little dogs bark "wuuf"
  • Big dogs bark "WUFFF! WUFFF!! WUFFF!!!"
• Define appropriate classes taking advantage of inheritance (search order)

Definition of a class "LittleDog", which possesses all properties common to all little dogs

/**/
.Dog~NEW       ~~"NAME="("Sweety")  ~Bark
.BigDog~NEW    ~~"NAME="("Grobian") ~Bark
.LittleDog~NEW ~~"NAME="("Arnie")   ~Bark
::CLASS  Dog          SUBCLASS Object
::ATTRIBUTE Name
::METHOD Bark
  SAY self~Name":" "Wuff Wuff" "-" self
::CLASS  BigDog   SUBCLASS dog
::METHOD Bark
  SAY self~Name":" "WUFFF! WUFFF!! WUFFF!!!" "-" self
  self~bark:super
::CLASS  "LittleDog" SUBCLASS dog
::METHOD Bark
  SAY self~Name":" "wuuf" "-" self

Output:

Sweety: Wuff Wuff - a DOG
Grobian: WUFFF! WUFFF!! WUFFF!!! - a BIGDOG
Grobian: Wuff Wuff - a BIGDOG
Arnie: wuuf - a LittleDog

• ::CLASS xyz
  • A class with the name XYZ is created

• ::Method mmm
  • A method with the identifier "MMM" is created

• PRIVATE, PUBLIC
  • Optional, default value: PUBLIC
  • If set to PRIVATE then the message can only be sent as: self~mmm
• GUARDED, UNGUARDED
  • Optional, default value: GUARDED
  • Determines whether method can be run in parallel to other methods
• CLASS
  • Optional, method is a class method
• PROTECTED, UNPROTECTED
  • Optional, default value: UNPROTECTED
  • If set to PROTECTED then access to this method can be supervised with the help of the Object Rexx Security Manager

• This directive is equivalent to "::METHOD mmm ATTRIBUTE" and causes the interpreter to create the following two methods by default:
  • A getter method named "MMM" and
  • A setter method named "MMM="
• If the option GET is given, then only the getter method gets created
• If the option SET is given, then only the setter method gets created

• This directive creates a class and an instance method named NAME which always returns VALUE

  say "pi:" .MyClass~pi "(from class)"
  o=.MyClass~new
  say "pi:" o~pi "(from instance)"
  
  ::CLASS MyClass
  ::CONSTANT pi 3.141592653589793238462643383279502884197

  Output:

  pi: 3.141592653589793238462643383279502884197 (from class)
  pi: 3.141592653589793238462643383279502884197 (from instance)

• By default this directive needs as delimiter the string "::END" starting at the first column of one of the following lines
  • The end marker string can be changed using the END delimiter option of the directive
• All lines between the start and the end of the directive will be stored in an array
• This array will be stored using NAME as its index in the .RESOURCES StringTable

• Methods and attributes are available to all instances (objects, values) of any Rexx class
  • Example: method INIT
    • Constructor, initializes a newly created object

• Interpreter creates an instance of this class ("method object") for each ::METHOD directive
  • Example: method SOURCE
    • Returns the source code of the method, if available

• Alarm objects allow dispatching messages at a later time
  • Such messages are carried out in parallel to other activities in the Object Rexx program ("multithreaded execution")
  • Dispatch time can be given
    • In hours, minutes, seconds starting from the time of initialization of the alarm object
    • As date and time
• Example: method CANCEL
  • Cancels an alarm object, the pending message will not be dispatched

• Monitor objects allow the monitoring of messages sent to objects
  • Example: method CURRENT
    • Returns the currently monitored object
  • Example: method DESTINATION
    • Allows to change the destination of the monitor
• Hint: ooRexx uses monitors in its .local environment directory
  • .input monitors .stdin, the ooRexx stdin stream object
  • .output monitors .stdout, the ooRexx stdout stream object
  • .error monitors .stderr, the ooRexx stderr stream object

• String objects possess all methods, which are the counterparts of all string functions in classic Rexx
  • Distinctive feature: string objects never change the value they were created with!

• String functions will be transformed "behind the curtain" by Object Rexx into the appropriate object-oriented version, by sending the appropriate messages to the string object!
  • Example: method REVERSE
    • Reverses the sequence of characters in a string

• Stem objects allow any string to be used as an index
  • The stem of the identifier includes the first dot

• Stem objects allow the collection of arbitrary objects with the help of string indices
  • Example: methods [] and []=

• Stream objects allow working with files (and communication devices)

  • Example: method NEW

    o = .stream ~NEW("test.dat")

    • Allows working with the file test.dat by sending the stream object o the appropriate messages, e.g. OPEN for opening, LINEIN (CHARIN) for reading from the file, LINEOUT (CHAROUT) for writing to the file, CLOSE for closing

• Class that allows to create a buffer from many little strings quickly
  • Comparable to Java's StringBuffer or StringBuilder classes
• Example methods
  • Method APPEND
    • Appends a string chunk to the buffer
  • Method STRING
    • Renders the current buffer as a single string object and returns it